# TireHolePoseApp.pro

QT       += core gui network serialport

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17

# 项目名称
TARGET = TireHolePoseApp

# 模板类型
TEMPLATE = app

# 定义宏
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += UNICODE
DEFINES += _UNICODE

# 编码设置
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

# Unix平台特定配置
unix:!macx {
    QMAKE_CXXFLAGS += -fPIC
}

INCLUDEPATH += $$PWD/Presenter/Inc

INCLUDEPATH += $$PWD/../../../Utils/VrCommon/Inc
INCLUDEPATH += $$PWD/../../../Utils/VrUtils/Inc

INCLUDEPATH += $$PWD/../../../Module/ShareMem/Inc

INCLUDEPATH += $$PWD/../TireHolePoseConfig/Inc
INCLUDEPATH += $$PWD/../../../Device/VrEyeDevice/Inc

INCLUDEPATH += $$PWD/../../../Nets/TCPServer/Inc

INCLUDEPATH += $$PWD/../../../Utils/CloudUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/UICommon/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppConfig/Inc
INCLUDEPATH += $$PWD/../../../Module/AuthModule/Inc
INCLUDEPATH += $$PWD/../../../Module/HandEyeCalib/Inc
INCLUDEPATH += $$PWD/../../../Module/HandEyeCalib/Utils/Inc

# 源文件
SOURCES += \
    Presenter/Src/ConfigManager.cpp \
    Presenter/Src/TireHolePosePresenter.cpp \
    Presenter/Src/DetectPresenter.cpp \
    Presenter/Src/PoseAxesBuilder.cpp \
    Presenter/Src/TireHolePoseTCPProtocol.cpp \
    Presenter/Src/TCPServerMethods.cpp \
    main.cpp \
    mainwindow.cpp \
    dialogalgoarg.cpp \
    resultitem.cpp

# 头文件
HEADERS += \
    Presenter/Inc/ConfigManager.h \
    Presenter/Inc/TireHolePosePresenter.h \
    Presenter/Inc/DetectPresenter.h \
    Presenter/Inc/PoseAxesBuilder.h \
    Presenter/Inc/TireHolePoseTCPProtocol.h \
    Presenter/Inc/RobotPose6D.h \
    mainwindow.h \
    dialogalgoarg.h \
    resultitem.h \
    Version.h

# UI文件
FORMS += \
    mainwindow.ui \
    dialogalgoarg.ui \
    resultitem.ui

# 资源文件
RESOURCES += \
    resources.qrc \
    ../../../AppUtils/UICommon/common_resources.qrc

# Windows任务栏图标配置
win32 {
    RC_ICONS = resource/logo.ico
}

win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../Utils/VrUtils/debug          -lVrUtils
    LIBS += -L../../../Utils/CloudUtils/debug       -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/debug      -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/debug     -lAppCommon
    LIBS += -L../TireHolePoseConfig/debug           -lTireHolePoseConfig
    LIBS += -L../../../AppUtils/AppConfig/debug     -lAppConfig
    LIBS += -L../../../Module/AuthModule/debug      -lAuthModule
    LIBS += -L../../../Module/HandEyeCalib/debug    -lHandEyeCalib
    LIBS += -L../../../Device/VrEyeDevice/debug     -lVrEyeDevice
    LIBS += -L../../../Nets/debug                -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/debug        -lShareMem
    LIBS += -L../../../Nets/debug                 -lVrModbus
    LIBS += -L../../../Nets/debug                 -lVrTcpServer

}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../Utils/VrUtils/release        -lVrUtils
    LIBS += -L../../../Utils/CloudUtils/release     -lCloudUtils
    LIBS += -L../../../AppUtils/UICommon/release    -lUICommon
    LIBS += -L../../../AppUtils/AppCommon/release   -lAppCommon
    LIBS += -L../TireHolePoseConfig/release         -lTireHolePoseConfig
    LIBS += -L../../../AppUtils/AppConfig/release   -lAppConfig
    LIBS += -L../../../Module/AuthModule/release    -lAuthModule
    LIBS += -L../../../Module/HandEyeCalib/release  -lHandEyeCalib
    LIBS += -L../../../Device/VrEyeDevice/release   -lVrEyeDevice
    LIBS += -L../../../Nets/release              -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/release      -lShareMem
    LIBS += -L../../../Nets/release               -lVrModbus
    LIBS += -L../../../Nets/release               -lVrTcpServer
}else:unix:!macx {
    LIBS += -L../TireHolePoseConfig               -lTireHolePoseConfig
    LIBS += -L../../../AppUtils/UICommon          -lUICommon
    LIBS += -L../../../AppUtils/AppCommon         -lAppCommon
    LIBS += -L../../../AppUtils/AppConfig         -lAppConfig
    LIBS += -L../../../Module/AuthModule          -lAuthModule
    LIBS += -L../../../Module/HandEyeCalib        -lHandEyeCalib
    LIBS += -L../../../Utils/CloudUtils           -lCloudUtils
    LIBS += -L../../../Device/VrEyeDevice         -lVrEyeDevice
    LIBS += -L../../../Nets                     -lModbusTCPServer
    LIBS += -L../../../Nets                     -lVrModbus
    LIBS += -L../../../Module/ShareMem            -lShareMem
    LIBS += -L../../../Nets                     -lVrTcpServer
    LIBS += -L../../../Utils/VrUtils              -lVrUtils

    LIBS += -lpthread
}

INCLUDEPATH += ../../../Device/SDK/VzNLSDK/_Inc
INCLUDEPATH += ../../../Device/SDK/VzNLSDK/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../Device/SDK/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../Device/SDK/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../Device/SDK/VzNLSDK/Arm/aarch64
    LIBS += -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}

# 工件孔定位算法（workpieceHolePositioning）
INCLUDEPATH += ../../../AppAlgo/workpieceHolePositioning/Inc

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../../AppAlgo/workpieceHolePositioning/Windows/x64/Release -lworkpieceHolePositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../../AppAlgo/workpieceHolePositioning/Windows/x64/Debug -lworkpieceHolePositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../../AppAlgo/workpieceHolePositioning/Arm/aarch64 -lworkpieceHolePositioning -lbaseAlgorithm
    LIBS += -L$$PWD/../../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui -lopencv_imgcodecs
}

# 添加libmodbus依赖
win32 {
    LIBS += -lws2_32
    LIBS += Advapi32.lib
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
    LIBS += -lrt
}
!isEmpty(target.path): INSTALLS += target

DISTFILES += \
    Version.md \
    Version.md