# BinocularMarkReceiver.pro

QT       -= core gui network

TARGET = BinocularMarkReceiver
TEMPLATE = lib
CONFIG += c++17 

# 全平台使用动态库
CONFIG += shared

# 定义宏
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += UNICODE
DEFINES += _UNICODE
DEFINES += BINOCULARMARKRECEIVER_LIBRARY

win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

unix {
    QMAKE_CXXFLAGS += -fPIC
}

# 包含路径
INCLUDEPATH += $$PWD/Inc
INCLUDEPATH += $$PWD/_Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/jsoncpp
INCLUDEPATH += $$PWD/../../VrNets/TCPClient/Inc

# 头文件
HEADERS += \
    Inc/IBinocularMarkReceiver.h \
    _Inc/BinocularMarkReceiver.h

# 源文件
SOURCES += \
    Src/BinocularMarkReceiver.cpp

# 库链接
win32 {
    CONFIG(debug, debug|release) {
        LIBS += -L../../VrNets/debug  -lVrTCPClient
        LIBS += -L../../Utils/VrUtils/debug -lVrUtils
    } else {
        LIBS += -L../../VrNets/release -lVrTCPClient
        LIBS += -L../../Utils/VrUtils/release -lVrUtils
    }
}

unix {
    LIBS += -L../../VrNets    -lVrTcpClient
    LIBS += -L../../Utils/VrUtils   -lVrUtils
    target.path = /usr/lib
}

!isEmpty(target.path): INSTALLS += target