QT += core gui widgets

TEMPLATE = lib
CONFIG += staticlib
CONFIG += c++17

TARGET = AppConfig

# Windows平台UTF-8编码支持
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

# Unix平台特定配置
unix:!macx {
    QMAKE_CXXFLAGS += -fPIC
}

# 包含路径
INCLUDEPATH += ./Inc
INCLUDEPATH += $$PWD/../AppCommon/Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/tinyxml2
INCLUDEPATH += $$PWD/../../Utils/VrCommon/Inc
INCLUDEPATH += $$PWD/../../Module/ShareMem/Inc       # ConfigMonitor

HEADERS += \
    Inc/VrHandEyeCalibConfig.h \
    Inc/ConfigXmlUtils.h \
    Inc/PathManager.h \
    Inc/ConfigMonitor.h \
    Inc/ConfigEncryption.h \
    Inc/BaseConfigManager.h

SOURCES += \
    Src/ConfigXmlUtils.cpp \
    Src/PathManager.cpp \
    Src/ConfigMonitor.cpp \
    Src/ConfigEncryption.cpp

# Windows平台库链接
win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../Module/ShareMem/release     -lShareMem
    LIBS += -L$$PWD/../../Utils/VrUtils/release       -lVrUtils
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../Module/ShareMem/debug       -lShareMem
    LIBS += -L$$PWD/../../Utils/VrUtils/debug         -lVrUtils
}else:unix:!macx {
    LIBS += -L../../Module/ShareMem     -lShareMem
    LIBS += -L../../Utils/VrUtils       -lVrUtils
    LIBS += -lpthread
}

# Default rules for deployment.
unix {
    target.path = /usr/lib
}
!isEmpty(target.path): INSTALLS += target