QT -= gui

TEMPLATE = lib
CONFIG += c++17
CONFIG += staticlib

DEFINES += VRZEROMQPUBSUB_LIBRARY

# 支持 UTF-8 编码
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CFLAGS += /utf-8
}

INCLUDEPATH += ./Inc
INCLUDEPATH += ./_Inc

# 项目通用工具
INCLUDEPATH += $$PWD/../../Utils/VrCommon/Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/ini

# CVrZeroMQPublisher / CVrZeroMQSubscriber 类都定义在 CVrZeroMQPubSub.h 中，
# 这里只列实际存在的文件，避免 qmake 找不到导致工程灰显或编译失败。
HEADERS += \
    Inc/IVrZeroMQPubSub.h \
    _Inc/CVrZeroMQPubSub.h

SOURCES += \
    Src/CVrZeroMQPubSub.cpp

# ZeroMQ SDK
INCLUDEPATH += $$PWD/../../SDK/ZeroMQ/include

win32 {
    CONFIG(debug, debug|release): {
        LIBS += -L$$PWD/../../SDK/ZeroMQ/Windows/x64/Debug   -llibzmq-v142-mt-gd-4_3_5
    } else {
        LIBS += -L$$PWD/../../SDK/ZeroMQ/Windows/x64/Release -llibzmq-v142-mt-4_3_5
    }
}
else:unix:!macx {
    LIBS += -L$$PWD/../../SDK/ZeroMQ/Arm/aarch64 -L$$PWD/../../SDK/ZeroMQ/Linux/x64
    LIBS += -lzmq
}

# VrUtils 链接
win32:CONFIG(debug, debug|release) {
    LIBS += -L../../Utils/VrUtils/debug   -lVrUtils
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../Utils/VrUtils/release -lVrUtils
}else:unix:!macx {
    LIBS += -L../../Utils/VrUtils         -lVrUtils
}

unix:!macx {
    QMAKE_CXXFLAGS += -fPIC
    target.path = /usr/lib
}

!isEmpty(target.path): INSTALLS += target