# WDRemoteReceiver.pro
# 远程设备控制 + 结果订阅 + 原始图像订阅 封装库
# 对外提供 IWDRemoteReceiver 接口；下游项目可直接复用，不与 DroneScrew 业务绑定

QT       += core network
QT       -= gui

TARGET   = WDRemoteReceiver
TEMPLATE = lib
CONFIG  += c++17

# 全平台使用动态库
CONFIG += shared

# 宏定义
DEFINES += QT_DEPRECATED_WARNINGS
DEFINES += WDREMOTERECEIVER_LIBRARY

# 让本库内部能使用 IVrZeroMQClient / IVrZeroMQSubscriber 的导入宏
win32 {
    DEFINES += VR_MQCLIENT_EXPORTS=0
    DEFINES += VR_MQPUBSUB_EXPORTS=0
}

unix {
    DEFINES += VR_MQCLIENT_EXPORTS=0
    DEFINES += VR_MQPUBSUB_EXPORTS=0
}

# UTF-8 编码
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CFLAGS   += /utf-8
}

# 头文件路径
INCLUDEPATH += $$PWD/Inc
INCLUDEPATH += $$PWD/_Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/jsoncpp
INCLUDEPATH += $$PWD/../../Utils/VrCommon/Inc
INCLUDEPATH += $$PWD/../AuthModule/Inc

# 依赖模块（ZeroMQ 控制 + 结果订阅 + 原始图像订阅）
INCLUDEPATH += $$PWD/../ZeroMQClient/Inc
INCLUDEPATH += $$PWD/../ZeroMQPubSub/Inc

# SDK 头（ZeroMQ）
INCLUDEPATH += $$PWD/../../SDK/ZeroMQ/include
INCLUDEPATH += $$PWD/../../SDK/OpenCV320/include

HEADERS += \
    Inc/IWDRemoteReceiver.h \
    _Inc/WDRemoteReceiver.h

SOURCES += \
    Src/WDRemoteReceiver.cpp

# 库链接
win32 {
    CONFIG(debug, debug|release) {
        LIBS += -L../ZeroMQClient/debug              -lZeroMQClient
        LIBS += -L../ZeroMQPubSub/debug              -lZeroMQPubSub
        LIBS += -L../AuthModule/debug                -lAuthModule
        LIBS += -L../../Utils/VrUtils/debug          -lVrUtils
    } else {
        LIBS += -L../ZeroMQClient/release            -lZeroMQClient
        LIBS += -L../ZeroMQPubSub/release            -lZeroMQPubSub
        LIBS += -L../AuthModule/release              -lAuthModule
        LIBS += -L../../Utils/VrUtils/release        -lVrUtils
    }

    # ZeroMQ SDK
    CONFIG(debug, debug|release) {
        LIBS += -L$$PWD/../../SDK/ZeroMQ/Windows/x64/Debug    -llibzmq-v142-mt-gd-4_3_5
    } else {
        LIBS += -L$$PWD/../../SDK/ZeroMQ/Windows/x64/Release  -llibzmq-v142-mt-4_3_5
    }

    LIBS += -lws2_32

    CONFIG(debug, debug|release) {
        LIBS += -L$$PWD/../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320d
    } else {
        LIBS += -L$$PWD/../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
    }
}

unix:!macx {
    LIBS += -L../ZeroMQClient        -lZeroMQClient
    LIBS += -L../ZeroMQPubSub        -lZeroMQPubSub
    LIBS += -L../AuthModule          -lAuthModule
    LIBS += -L../../Utils/VrUtils    -lVrUtils

    LIBS += -L$$PWD/../../SDK/ZeroMQ/Arm/aarch64  -lzmq
    LIBS += -L$$PWD/../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgcodecs
    LIBS += -lpthread

    QMAKE_CXXFLAGS += -fPIC

    target.path = /usr/lib
}

!isEmpty(target.path): INSTALLS += target