# RsLidarDevice 测试程序

TEMPLATE = app
TARGET = RsLidarTest
CONFIG += c++17 console
CONFIG -= qt

win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

# 仅依赖 RsLidarDevice 公共接口（不含 rs_driver SDK 头文件）
INCLUDEPATH += $$PWD/../../Device/RsLidarDevice/Inc

# CloudShow 模块
INCLUDEPATH += $$PWD/../../Module/CloudShow/Inc

# 项目标准类型（SVzNLPointXYZI 等）
INCLUDEPATH += $$PWD/../../Utils/VrCommon/Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/Inc
INCLUDEPATH += $$PWD/../../Utils/CloudUtils/Inc

SOURCES += \
    main.cpp

# PCL + VTK 路径（CloudShow 是静态库，最终 exe 需解析 PCL DLL 符号）
PCL_LIB_DIR   = $$PWD/../../SDK/pcl-1.14.0/lib
BOOST_LIB_DIR = $$PWD/../../SDK/pcl-1.14.0/3rdParty/Boost/lib
VTK_LIB_DIR   = $$PWD/../../SDK/pcl-1.14.0/3rdParty/VTK/lib

# VTK 版本后缀
VTK_VER = -9.3

# PCL 库
win32:CONFIG(release, debug|release) {
    PCL_LIBS  = -lpcl_common -lpcl_io -lpcl_visualization
    PCL_LIBS += -lpcl_filters -lpcl_kdtree -lpcl_search -lpcl_octree -lpcl_sample_consensus
    VTK_SUFFIX = $${VTK_VER}
} else:win32:CONFIG(debug, debug|release) {
    PCL_LIBS  = -lpcl_commond -lpcl_iod -lpcl_visualizationd
    PCL_LIBS += -lpcl_filtersd -lpcl_kdtreed -lpcl_searchd -lpcl_octreed -lpcl_sample_consensusd
    VTK_SUFFIX = $${VTK_VER}-gd
} else:unix:!macx {
    PCL_LIBS  = -lpcl_common -lpcl_io -lpcl_visualization
    VTK_SUFFIX = $${VTK_VER}
}

# CloudShow 静态库
UTILS_BUILD = $$PWD/../../GrabBagPrj/build/Utils
win32:CONFIG(debug, debug|release) {
    LIBS += -L../../Device/RsLidarDevice/debug  -lRsLidarDevice
    LIBS += -L../../Module/CloudShow/debug      -lCloudShow
    LIBS += -L$${UTILS_BUILD}/CloudUtils/debug  -lCloudUtils
    LIBS += -L$${UTILS_BUILD}/VrUtils/debug     -lVrUtils
} else:win32:CONFIG(release, debug|release) {
    LIBS += -L../../Device/RsLidarDevice/release    -lRsLidarDevice
    LIBS += -L../../Module/CloudShow/release        -lCloudShow
    LIBS += -L$${UTILS_BUILD}/CloudUtils/release    -lCloudUtils
    LIBS += -L$${UTILS_BUILD}/VrUtils/release       -lVrUtils
} else:unix:!macx {
    LIBS += -L../../Device/RsLidarDevice    -lRsLidarDevice
    LIBS += -L../../Module/CloudShow        -lCloudShow
    LIBS += -L$${UTILS_BUILD}/CloudUtils    -lCloudUtils
    LIBS += -L$${UTILS_BUILD}/VrUtils       -lVrUtils
}

LIBS += -L$$PCL_LIB_DIR -L$$BOOST_LIB_DIR -L$$VTK_LIB_DIR
LIBS += $$PCL_LIBS

win32 {
    VTK_BASE = $${VTK_LIB_DIR}/
    LIBS += \
        $${VTK_BASE}vtksys$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkChartsCore$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkCommonColor$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkCommonComputationalGeometry$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkCommonCore$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkCommonDataModel$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkCommonExecutionModel$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkCommonMath$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkCommonMisc$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkCommonTransforms$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkFiltersCore$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkFiltersExtraction$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkFiltersGeneral$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkFiltersGeometry$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkFiltersModeling$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkFiltersSources$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkImagingCore$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkImagingSources$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkInteractionImage$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkInteractionStyle$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkInteractionWidgets$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkIOCore$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkIOGeometry$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkIOImage$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkIOLegacy$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkIOPLY$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkRenderingAnnotation$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkRenderingContext2D$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkRenderingContextOpenGL2$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkRenderingCore$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkRenderingFreeType$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkRenderingLOD$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkRenderingOpenGL2$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkViewsContext2D$${VTK_SUFFIX}.lib \
        $${VTK_BASE}vtkViewsCore$${VTK_SUFFIX}.lib

    LIBS += -lws2_32
}