# MvsDevice.pro
# 海康威视 MVS 工业相机设备封装库

CONFIG -= qt

TEMPLATE = lib
CONFIG += staticlib
DEFINES += MVSDEVICE_LIBRARY

CONFIG += c++17

# 支持 UTF-8 编码
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CFLAGS += /utf-8
}

# 头文件路径
INCLUDEPATH += ./Inc
INCLUDEPATH += ./_Inc
INCLUDEPATH += $$PWD/../../Utils/VrCommon/Inc
INCLUDEPATH += $$PWD/../../Utils/VrUtils/Inc

# 源文件
SOURCES += \
    Src/MvsDevice.cpp \
    Src/MvsSDKManager.cpp

# 头文件
HEADERS += \
    Inc/IMvsDevice.h \
    Inc/MvsDevice_global.h \
    _Inc/MvsDevice.h \
    _Inc/MvsSDKManager.h


# VrUtils 链接（用于日志）
win32:CONFIG(debug, debug|release) {
    LIBS += -L../../Utils/VrUtils/debug                     -lVrUtils
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../Utils/VrUtils/release                   -lVrUtils
}else:unix:!macx {
    LIBS += -L../../Utils/VrUtils                           -lVrUtils
    LIBS += -lpthread
}

# MVS SDK 头文件 / 库路径（全部从仓库内 SDK 取，不依赖系统安装）
# - Windows: MVS_Win_STD_5.0.0_260417/Development/{Includes,Libraries/win64}
# - Linux/ARM: MVS_STD_V3.0.1_251113/MVS-3.0.1_aarch64_20251113/{include,lib/aarch64}

win32 {
    MVS_WIN_ROOT = $$PWD/../../SDK/Device/MVS/MVS_Win_STD_5.0.0_260417/Development
    INCLUDEPATH += $$MVS_WIN_ROOT/Includes

    LIBS += -L$$MVS_WIN_ROOT/Libraries/win64 -lMvCameraControl
    LIBS += -lws2_32
}
else:unix:!macx: {
    MVS_ARM_ROOT = $$PWD/../../SDK/Device/MVS/MVS_STD_V3.0.1_251113/MVS-3.0.1_aarch64_20251113
    INCLUDEPATH += $$MVS_ARM_ROOT/include

    LIBS += -L$$MVS_ARM_ROOT/lib/aarch64 -lMvCameraControl
}

# Unix/Linux 平台设置
unix:!macx {
    message("build MvsDevice for unix")

    # 生成位置无关代码
    QMAKE_CXXFLAGS += -fPIC

    # 添加系统库依赖
    LIBS += -ldl -lpthread -lrt

    target.path = /usr/lib
}

!isEmpty(target.path): INSTALLS += target