QT       += core
QT       += network
QT       += gui
QT       += xml

TEMPLATE = app
TARGET   = DroneScrewServer

CONFIG += c++17 console
CONFIG -= app_bundle

# UTF-8 缂栫爜
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
}

DEFINES += QT_DEPRECATED_WARNINGS

# 澶存枃浠惰矾寰?
INCLUDEPATH += $$PWD/../../../Utils/VrCommon/Inc
INCLUDEPATH += $$PWD/../../../Utils/VrUtils/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppCommon/Inc
INCLUDEPATH += $$PWD/../../../AppUtils/AppConfig/Inc

# 璁惧锛歁vsDevice
INCLUDEPATH += $$PWD/../../../Device/MvsDevice/Inc

# 妯″潡锛歓eroMQ Server + PubSub + FFMediaStream + WDRemoteReceiver(澶村鐢?
INCLUDEPATH += $$PWD/../../../VrNets/ZeroMQServer/Inc
INCLUDEPATH += $$PWD/../../../VrNets/ZeroMQPubSub/Inc
INCLUDEPATH += $$PWD/../../../Module/FFMediaStream/Inc
INCLUDEPATH += $$PWD/../../../Module/WDRemoteReceiver/Inc
INCLUDEPATH += $$PWD/../../../Module/AuthModule/Inc

# Protobuf / ZeroMQ 澶?
INCLUDEPATH += $$PWD/../../../SDK/Protobuf_3_20/include
INCLUDEPATH += $$PWD/../../../VrNets/SDK/ZeroMQ/include

# MPP headers
INCLUDEPATH += $$PWD/../../../Module/SDK/mpp/include
INCLUDEPATH += $$PWD/../../../Module/SDK/mpp/include/rockchip


# 绠楁硶鍗犱綅鎺ュ彛
INCLUDEPATH += $$PWD/Algo
INCLUDEPATH += $$PWD/../../../AppAlgo/stereo_bolt_delivery/include

SOURCES += \
    main.cpp \
    DroneScrewServerPresenter.cpp \
    DroneScrewZmqProtocol.cpp \
    MjpegEncoder.cpp \
    Algo/DroneScrewAlgoStub.cpp

HEADERS += \
    DroneScrewServerPresenter.h \
    DroneScrewZmqProtocol.h \
    MjpegEncoder.h \
    Version.h \
    Algo/IDroneScrewAlgo.h \
    Algo/DroneScrewAlgoStub.h

# ====== Windows 閾炬帴 ======
win32:CONFIG(debug, debug|release) {
    LIBS += -L../../../Device/MvsDevice/debug          -lMvsDevice
    LIBS += -L../../../Module/FFMediaStream/debug      -lFFMediaStream
    LIBS += -L../../../VrNets/debug       -lZeroMQServer
    LIBS += -L../../../VrNets/debug       -lZeroMQPubSub
    LIBS += -L../../../Module/AuthModule/debug         -lAuthModule
    LIBS += -L../../../Utils/VrUtils/debug             -lVrUtils
    LIBS += -L../../../AppUtils/AppCommon/debug        -lAppCommon
    LIBS += -L../../../AppUtils/AppConfig/debug        -lAppConfig
    LIBS += -L../../../VrNets/debug    -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/debug           -lShareMem
    LIBS += -L../../../VrNets/debug                    -lVrModbus
}else:win32:CONFIG(release, debug|release){
    LIBS += -L../../../Device/MvsDevice/release        -lMvsDevice
    LIBS += -L../../../Module/FFMediaStream/release    -lFFMediaStream
    LIBS += -L../../../VrNets/release     -lZeroMQServer
    LIBS += -L../../../VrNets/release     -lZeroMQPubSub
    LIBS += -L../../../Module/AuthModule/release       -lAuthModule
    LIBS += -L../../../Utils/VrUtils/release           -lVrUtils
    LIBS += -L../../../AppUtils/AppCommon/release      -lAppCommon
    LIBS += -L../../../AppUtils/AppConfig/release      -lAppConfig
    LIBS += -L../../../VrNets/release  -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem/release         -lShareMem
    LIBS += -L../../../VrNets/release                  -lVrModbus
}else:unix:!macx {
    # ====== Linux/ARM 閾炬帴 ======
    LIBS += -L../../../Device/MvsDevice                -lMvsDevice
    LIBS += -L../../../Module/FFMediaStream            -lFFMediaStream
    LIBS += -L../../../VrNets             -lZeroMQServer
    LIBS += -L../../../VrNets             -lZeroMQPubSub
    LIBS += -L../../../Module/AuthModule               -lAuthModule
    LIBS += -L../../../AppUtils/AppCommon              -lAppCommon
    LIBS += -L../../../AppUtils/AppConfig              -lAppConfig
    LIBS += -L../../../VrNets          -lModbusTCPServer
    LIBS += -L../../../Module/ShareMem                 -lShareMem
    LIBS += -L../../../VrNets                          -lVrModbus
    LIBS += -L../../../Utils/VrUtils                   -lVrUtils
    DEFINES += DRONESCREW_STEREO_BOLT_DIRECT_LINK
    LIBS += -L$$PWD/../../../AppAlgo/stereo_bolt_delivery/lib -lstereo_bolt
    OPENCV450_LIB_DIR = $$PWD/../../../SDK/OpenCV450/Arm/aarch64/lib
    INCLUDEPATH += $$PWD/../../../SDK/OpenCV450/Arm/aarch64/include/opencv4
    LIBS += -L$${OPENCV450_LIB_DIR}
    LIBS += -lopencv_imgcodecs -lopencv_imgproc -lopencv_calib3d -lopencv_core
    QMAKE_LFLAGS += -Wl,-rpath-link,$${OPENCV450_LIB_DIR}

    # MVS SDK
    LIBS += -L$$PWD/../../../Device/SDK/MVS/MVS_STD_V3.0.1_251113/MVS-3.0.1_aarch64_20251113/lib/aarch64
    LIBS += -lMvCameraControl

    # 绯荤粺搴擄紙鏉垮瓙鑷甫锛?
    LIBS += -lrga

    # MPP 鍔ㄦ€佸簱 + FFmpeg 闈欐€佸簱鎼滅储璺緞
    MPP_LIB_DIR = $$PWD/../../../Module/SDK/mpp/lib
    FFMPEG_LIB_DIR = $$PWD/../../../Module/SDK/ffmpeg-rockchip/lib
    LIBS += -L$${MPP_LIB_DIR}
    LIBS += -L$${FFMPEG_LIB_DIR}

    # FFmpeg-rockchip 闈欐€佸簱
    # --whole-archive锛氳В鍐?.a 闂村惊鐜緷璧?+ ff_log_level 绛夊唴閮ㄧ鍙?
    # --allow-multiple-definition锛歭ibavcodec 鍜?libswscale 閮界紪璇戜簡 half2float.o锛堥噸澶嶄絾瀹屽叏鐩稿悓锛?
    LIBS += -Wl,--whole-archive
    LIBS += -lavformat -lavcodec -lswscale -lavutil -lswresample
    LIBS += -Wl,--no-whole-archive
    LIBS += -Wl,--allow-multiple-definition

    # FFmpeg / MPP 浼犻€掍緷璧?
    LIBS += -lrockchip_mpp -lz -llzma -ldrm -lpthread -ldl

    # ZeroMQ / Protobuf
    LIBS += -L$$PWD/../../../VrNets/SDK/ZeroMQ/Arm/aarch64         -lzmq
    LIBS += -L$$PWD/../../../SDK/Protobuf_3_20/Arm/aarch64  -lprotobuf

    LIBS += -lpthread -ldl

    # 鍏佽鏈畾涔夌鍙凤紙杩愯鏃剁敱绯荤粺搴撴彁渚涳級
    QMAKE_LFLAGS += -Wl,--allow-shlib-undefined
}

# Windows 绯荤粺搴?
win32 {
    LIBS += -lws2_32
    LIBS += Shell32.lib

    # MVS SDK锛圡vsDevice 鏄潤鎬佸簱锛孡IBS 涓嶄細浼犻€掞紝闇€瑕佽繖閲屽啀閾句竴娆★級
    # 鍏ㄩ儴浠庝粨搴撳唴 SDK 鍙栵紝涓嶄緷璧栫郴缁熷畨瑁?
    LIBS += -L$$PWD/../../../Device/SDK/MVS/MVS_Win_STD_5.0.0_260417/Development/Libraries/win64 -lMvCameraControl

    # ZeroMQ
    CONFIG(release, debug|release): {
        LIBS += -L$$PWD/../../../VrNets/SDK/ZeroMQ/Windows/x64/Release        -llibzmq-v142-mt-4_3_5
        LIBS += -L$$PWD/../../../SDK/Protobuf_3_20/Windows/x64/Release -llibprotobuf
    } else {
        LIBS += -L$$PWD/../../../VrNets/SDK/ZeroMQ/Windows/x64/Debug         -llibzmq-v142-mt-gd-4_3_5
        LIBS += -L$$PWD/../../../SDK/Protobuf_3_20/Windows/x64/Debug  -llibprotobuf
    }
}

unix {
    target.path = /opt/dronescrewserver
    LIBS += -lrt
}

!isEmpty(target.path): INSTALLS += target