QT       += core gui network

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17

# 强制使用UTF-8编码
QMAKE_CXXFLAGS += /utf-8

# 定义版本号
DEFINES += APP_VERSION=\\\"1.0.0\\\"

# 定义静态库模式（不导入）
DEFINES += FAIRINO_WRAPPER_LIB

# 输出目录配置（由主项目决定）
CONFIG(debug, debug|release) {
    TARGET = ControlAppd
} else {
    TARGET = ControlApp
}

SOURCES += \
    main.cpp \
    mainwindow.cpp \
    DemoControlPresenter.cpp \
    WorkflowWidget.cpp \
    DialogConfig.cpp

HEADERS += \
    mainwindow.h \
    DemoControlPresenter.h \
    WorkflowWidget.h \
    DialogConfig.h \
    Version.h

FORMS += \
    mainwindow.ui \
    dialogconfig.ui

# 包含路径
INCLUDEPATH += \
    $$PWD/../../AppUtils/AppCommon/Inc \
    $$PWD/../../AppUtils/UICommon/Inc \
    $$PWD/../../Module/ModbusTCPClient/Inc \
    $$PWD/../../Robot/FairinoWrapper \
    $$PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/src/include/Robot-CN  \
    $$PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/src/include    \
    $$PWD/../../VrUtils/Inc

# Windows平台库链接
win32:CONFIG(release, debug|release): {
    LIBS += -L$$OUT_PWD/../../AppUtils/AppCommon/release         -lAppCommon
    LIBS += -L$$OUT_PWD/../../AppUtils/UICommon/release          -lUICommon
    LIBS += -L$$OUT_PWD/../../Module/ModbusTCPClient/release     -lModbusTCPClient
    LIBS += -L$$OUT_PWD/../../Utils/VrUtils/release              -lVrUtils
    LIBS += -L$$OUT_PWD/../../Robot/FairinoWrapper/release/      -lFairinoWrapper
    LIBS += -L$$OUT_PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/release/ -lfairino
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$OUT_PWD/../../AppUtils/AppCommon/debug           -lAppCommond
    LIBS += -L$$OUT_PWD/../../AppUtils/UICommon/debug            -lUICommond
    LIBS += -L$$OUT_PWD/../../Module/ModbusTCPClient/debug       -lModbusTCPClientd
    LIBS += -L$$OUT_PWD/../../Utils/VrUtils/debug                -lVrUtilsd
    LIBS += -L$$OUT_PWD/../../Robot/FairinoWrapper/debug/        -lFairinoWrapperd
    LIBS += -L$$OUT_PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/debug/ -lfairinod
}

# Windows系统库
win32 {
    LIBS += -lws2_32
}

# Windows任务栏图标配置
win32 {
    RC_ICONS = logo.ico
}

# 资源文件
RESOURCES += \
    $$PWD/../../AppUtils/UICommon/common_resources.qrc \
    resource.qrc